和大家一起来探讨一下VB.NET通信程序及其在windows平台下的通信软件设计方法，结合具体实例给出了基本的通信程序，希望对大家有帮助。1992年crescent software inc.公司专为vb设计mscomm.vbx用户通信控件，它提供了通过串口发送和接收数据的串行通信能力，不但包括了全部windows api中关于串行通信的16个函数所完成的功能，而且开拓了更多的使用户设计方便的对象属性来满足不同用户不同业务的需求。目前国内众多的vb资料中很少涉及该通信控件的介绍，本文将详细介绍mscomm.vbx通信控件及编程方法，并结合工作中的一个实例给出基本通信程序。
1 mscomm.vbx通信控件描述
mscomm.vbx通信控件可直接从vb的toolbox中加入窗体form，即可用其进行通信。若toolbox中无此控件，则用tools的custom controls 将mscomm.vbx从windows的system子目录中加入vb的toolbox中。
1.1 通信方式
mscomm.vbx有2种不同的方式来处理和解决各类通信软件的开发和设计问题
1)事件驱动。它与c/c++写windows 软件时的窗口回调函数类似，是1种功能强大的处理问题的方法。在实际工作中，往往要处理许多通信中的相关事件，例如：当线路数据到达本端或cd线和rts信号线状态发生变化时，要求我们使用相应的事件来跟踪和处理，该控件是使用oncomm事件来实现的，它也包括检测和处理通信错误等方面的问题，commevent 值返回最近的通信事件或错误的数字代码。通信控件详细的错误和事件举例有：
mscomm-er-break 收到1个break signal
mscomm-er-cdto cd 信号超时
……
mscomm-ev-cd cd信号改变
……
2)查询方式。由程序设计者负责读取commevent的值并处理所发生的错误或事件。通常简单的应用程序设计可采用这种办法。
1.2 通信控件的属性
利用通信控件编制VB.NET通信程序，关键是准确理解设置通信控件的属性。mscomm.vbx提供了27个关于通信控件方面的属性，例如：
commport：设置或返回通信口编号。
settings：设置或返回以字符串形式出现的数据通信格式：波特率、校验、数据位和停 止位。
portopen：设置或返回通信口状态(包括打开和关闭1个通信口)
……
2.实例
本程序应用背景为dcc95型静电除尘器自动监控系统软件，解决1个pc工控机(主站)与32个单片机(子站)之间的通信问题。主站与子站之间这总线式网络结构，采用rs-485通信标准，以问答方式进行数据通信。由于32个子站与主站发送通信命令(下行命令)，主站在接收子站发回的相应回答命令(上行命令)后继续发送下行命令的通信形式。根据系统功能的要求，主站需发送2种类型的命令：(1)同期命令，它由定时器触发引起，每隔ls周期发送1次;(2)非周期性命令，它由操作者按动相应命令按钮引起，非周期性发送。自动监控系统软件安装在主站上，而VB.NET通信程序作为自动监控系统软件的一部分也安装在主站上。
本文仅列出调试VB.NET通信程序时进行试验用的基本演示程序清单。试验时，用1台pc机作为主站，另一台pc机模拟32个子站的工作，两台pc机之间采用rs232c串口通信。往主站的通信演示程序窗体(form)中加入1个通信控件、2个定时器控件和1个命令按钮控件，通信控件(mscomm1)用于访问串口，发送和接收数据;periodic定时器控件(periodic)用于控制每秒由主站向各子站发送周期性命令;命令按钮控件(nonperiodic-command)与nonperiodic定时器控件(nonperiodic)用于发送非周期性命令。数据传送采用事件驱动的通信方式，根据不同的发送命令设置rtreshlod属性，从而引起oncomm事件以接收数据。
2.1 窗体各控件初始化程序
设置通信串口工作参数，设置periodic定时器的在断间隔为ls, nonperiodic定时器的中断间隔为0.5s。
sub form-load ()
mscomm1.commport=2 '选用com2串行口
mscomm1.settings="9600，n8，1" '波特率9600，无奇偶校验位，8位数据位1位停止位
mscomm1.inputlen=0 'input将读取接收缓冲区的全部内容
mscomm1.inbuffersize=1024 '设置接收缓冲区的字节长度
mscomm1.portopen=true '打开通信口
mscomm1.inbuffercount=0 '清除发送缓冲区数据
mscomm1.outbuffercount=0 '清除接收缓冲区数据
periodic.inteval=100 '设置ls定时间隔，使遥测命令每隔ls发送1次
nonperiodic.inteval=500 '设置0.5s定时间隔，查询命令按钮是否处于激活状态以确定是否发送周期性命令
command-pressed=false '命令按钮为未激活状态
during- periodic=false '周期性命令数据传输尚未开始
during- nonperiodic=false '非周期性命令数据传输尚未开始
end sub
2.2 非周期性命令发送程序
根据命令按钮状态及周期性命令数据传输状态，在nonperiodic定时器的中断程序中发送非周期性命令。
sub nonperiodic-command-click ()
command-pressed=true '命令按钮激活
end sub
sub nonperiodic-timer ()
if during- periodic=true or command-pressed=false
then exit sub '若周期性命令数据传输尚未结束或命令按钮处于激活状态，则退出发送非周期性命令程序。
command-pressed=false '命令按钮恢复为未激活状态
call senddata (nonperiodic-command) '发送非周期性命令
mscomm1.rthreshold=r-nonperiodic-byte'发送非周期性命令后，设置rthreshold属性，使主站接收所设定的字节数后引发oncomm事件
end sub
2.3 periodic定时器程序
在periodic定时器的中断程序中发送周期性命令：
sub periodic-timer ()
if during- nonperiodic=true then exit sub '若非周期性命令数据传输尚未结束，则退出发送非周期性命令程序。
during-periodic=true '设置周期性命令数据传输状态为正在进行中
call senddata (periodic-command) '发送周期性命令
mscomm1.rthreshold=r-periodic-byte '发送周期性命令后，主站接收r-remot- edata-byte个字节，可引发oncomm 事件
end sub
2.4 oncomm事件程序
根据rthreshold属性设置值，当接收缓存区内接收到相应字节的字符时，引发oncomm事件，在中断程序中接收数据。
sub mscomm1-oncomm () select case mscomm1.commevent '在此可插入处理各种不同错误或事件的代码
case mscomm-ev-receive
receivestring$=mscomm1.input
select case mscomm1.rthreshold
case r-periodic-byte '周期性命令的应答数据
call disposedata(periodic-command) '处理接收数据
during periodic=false '设置周期性命令数据传输状态为结束
case r-nonperiodic-byte '非周期性命令的应答数据
call disposedata(nonperiodic-command) '处理接收数据
during-nonperiodic=false '设置非周期性命令数据传输状态为结束
end select
end select
随着vb版本的不断升级，vb将成为最快速、易用、强劲的应用开发工具，是企业级客户/服务器应用软件开发的首选工具之一。
这是我3年前的一个例子，最近翻出来回忆一下。
串口是计算机上一种非常通用设备通信的协议。大多数计算机包含两个基于RS232的串口，现在配电脑好像只有一个。串口同时也是仪器仪表设备通用的通信协议；很多GPIB兼容的设备也带有RS-232口。同时，串口通信协议也可以用于获取远程采集设备的数据。串口通信在工控领域用途很广。
串口通信的概念非常简单，串口按位（bit）发送和接收字节。尽管比按字节（byte）的并行通信慢，但是串口可以在使用一根线发送数据的同时用另一根线接收数据。它很简单并且能够实现远距离通信。比如IEEE488定义并行通行状态时，规定设备线总常不得超过20米，并且任意两个设备间的长度不得超过2米；而对于串口而言，长度可达1200米。
典型地，串口用于ASCII码字符的传输。通信使用3根线完成：（1）地线，（2）发送，（3）接收。由于串口通信是异步的，端口能够在一根线上发送数据同时在另一根线上接收数据。其他线用于握手，但是不是必须的。串口通信最重要的参数是波特率、数据位、停止位和奇偶校验。对于两个进行通行的端口，这些参数必须匹配：
a，波特率：这是一个衡量通信速度的参数。它表示每秒钟传送的bit的个数。例如300波特表示每秒钟发送300个bit。当我们提到时钟周期时，我们就是指波特率例如如果协议需要4800波特率，那么时钟是4800Hz。这意味着串口通信在数据线上的采样率为4800Hz。通常电话线的波特率为14400，28800和36600。波特率可以远远大于这些值，但是波特率和距离成反比。高波特率常常用于放置的很近的仪器间的通信，典型的例子就是GPIB设备的通信。
b，数据位：这是衡量通信中实际数据位的参数。当计算机发送一个信息包，实际的数据不会是8位的，标准的值是5、7和8位。如何设置取决于你想传送的信息。比如，标准的ASCII码是0～127（7位）。扩展的ASCII码是0～255（8位）。如果数据使用简单的文本（标准 ASCII码），那么每个数据包使用7位数据。每个包是指一个字节，包括开始/停止位，数据位和奇偶校验位。由于实际数据位取决于通信协议的选取，术语“包”指任何通信的情况。
c，停止位：用于表示单个包的最后一位。典型的值为1，1.5和2位。由于数据是在传输线上定时的，并且每一个设备有其自己的时钟，很可能在通信中两台设备间出现了小小的不同步。因此停止位不仅仅是表示传输的结束，并且提供计算机校正时钟同步的机会。适用于停止位的位数越多，不同时钟同步的容忍程度越大，但是数据传输率同时也越慢。
d，奇偶校验位：在串口通信中一种简单的检错方式。有四种检错方式：偶、奇、高和低。当然没有校验位也是可以的。对于偶和奇校验的情况，串口会设置校验位（数据位后面的一位），用一个值确保传输的数据有偶个或者奇个逻辑高位。例如，如果数据是011，那么对于偶校验，校验位为0，保证逻辑高的位数是偶数个。如果是奇校验，校验位位1，这样就有3个逻辑高位。高位和低位不真正的检查数据，简单置位逻辑高或者逻辑低校验。这样使得接收设备能够知道一个位的状态，有机会判断是否有噪声干扰了通信或者是否传输和接收数据是否不同步。
串口通信还有一个参数是单工、半双工和双工。
如果在通信过程的任意时刻，信息只能由一方A传到另一方B，则称为单工。
如果在任意时刻，信息既可由A传到B，又能由B传A，但只能由一个方向上的传输存在，称为半双工传输。
如果在任意时刻，线路上存在A到B和B到A的双向信号传输，则称为全双工。
电话线就是二线全双工信道。 由于采用了回波抵消技术，双向的传输信号不致混淆不清。双工信道有时也将收、发信道分开，采用分离的线路或频带传输相反方向的信号，如回线传输。
在调试时可以用串口助手和windows的超级终端，不要带电插拔串口，容易烧毁。
在VB.NET中提供了IO.Ports类，是我们的编程变得很简单，下面是我的例子：
Form1.vb
[vb] view plain copy
- Imports System.IO.Ports
-
- Public Class Form1
-
- Dim WithEvents RS232 As SerialPort
- Delegate Sub SetTextCallback(ByVal InputString As String) '声明一个代理
-
- Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
- For Each sp As String In SerialPort.GetPortNames()
- cmbCom.Items.Add(sp)
- Next
- cmbCom.Sorted = True
- cmbCom.SelectedIndex = 0
- End Sub
-
- Private Sub btnStart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnStart.Click
- Dim mBaudRate As Integer
- Dim mParity As IO.Ports.Parity
- Dim mDataBit As Integer
- Dim mStopBit As IO.Ports.StopBits
- Dim mPortName As String
-
- mPortName = cmbCom.SelectedItem.ToString
- mBaudRate = 9600
- mParity = Parity.None
- mDataBit = 8
- mStopBit = StopBits.One
-
- RS232 = New IO.Ports.SerialPort(mPortName, mBaudRate, mParity, mDataBit, mStopBit)
-
- If Not RS232.IsOpen Then
- RS232.Open()
- btnSend.Enabled = True
- RS232.ReceivedBytesThreshold = 1 '设置引发事件的门限值
- Else
- MsgBox("通讯端口打开错误！", MsgBoxStyle.Critical)
- End If
- End Sub
-
-
- Private Sub RS232_DataReceived(ByVal sender As Object, ByVal e As System.IO.Ports.SerialDataReceivedEventArgs) Handles RS232.DataReceived
- Dim InByte() As Byte, ReadCount As Integer, strRead As String
- If RS232.BytesToRead <= 0 Then Exit Sub
- ReDim InByte(RS232.BytesToRead - 1)
- ReadCount = RS232.Read(InByte, 0, RS232.BytesToRead)
- strRead = ""
- If ReadCount = 0 Then
- Exit Sub
- Else
- For Each bData As Byte In InByte
- strRead += bData.ToString & vbCrLf '若有数据则加到接收文本框
- DisplayText(strRead)
- Next
- End If
-
-
- End Sub
- '*************************************************
- '代理子程序
- '处理上述通信端口的接收事件
- '由于欲将数据显示到接收文本框中，因此必须检查
- '是否由另外得Thread所调用的，若是，则必须先
- '建立代理对象
- 'Invoke用于在拥有控件基础窗口控制代码的线程上
- '运行代理
- '*************************************************
- Private Sub DisplayText(ByVal comData As String)
- '如果调用txtReceive的另外的线程，返回true
- If Me.txtReceive.InvokeRequired Then
- '利用代理类型建立对象，并指定代理的函数
- Dim d As New SetTextCallback(AddressOf DisplayText)
- Me.Invoke(d, New Object() {comData}) '以指定的自变量列表调用函数
- Else '相同的线程
- 'showstring(comData) '将收到的数据填入接收文本框中
- Me.txtReceive.Text += comData
- End If
- End Sub
-
- Private Sub btnClose_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnClose.Click
- If RS232 Is Nothing OrElse Not RS232.IsOpen Then '尚未打开
- MsgBox("通讯端口尚未打开", MsgBoxStyle.Critical Or MsgBoxStyle.OkCancel)
- Else
- RS232.Close()
- btnStart.Enabled = False
- btnClose.Enabled = False
- RS232 = Nothing
- End If
- End Sub
-
- Private Sub btnEnd_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnEnd.Click
- If Not RS232 Is Nothing Then
- If RS232.IsOpen Then RS232.Close()
- End If
- End
- End Sub
-
- Private Sub btnSend_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSend.Click
- Dim bDataOut(0) As Byte
- Try
- bDataOut(0) = CType(Me.txtSend.Text, Byte) '将类型转换为字节
- RS232.Write(bDataOut, 0, 1)
- Catch ex As Exception
- MessageBox.Show("输入数值错误：" + ex.ToString, "错误通知：", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
- End Try
- End Sub
-
- Private Sub cmbCom_KeyPress(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles cmbCom.KeyPress
- e.KeyChar = ChrW(0) '禁止用户在其中输入任何文字
- End Sub
-
- Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
- Me.Hide()
- Form2.Show()
- End Sub
- End Class
Form2.vb
[vb] view plain copy
- '**************************************************************
- '时间：2008-11-08
- '作者：lincyang
- '实际应用中，串行通信的数据可能一次发送大量的数据，
- '发送之前就必须将数据先编码，
- '将其编成我们需要的字节数组数据，
- '才能将这些数据以字节的方式发送出去
- '目前操作系统使用的字符数据是Unicode：所有的字符均使用
- '两个字节来表示一个字符
- '**************************************************************
-
- Imports System.IO.Ports
- Imports System.Text
- Public Class Form2
- Dim RS232 As SerialPort
- Private Sub Form2_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
- For Each sp As String In SerialPort.GetPortNames()
- cmbCom.Items.Add(sp)
- Next
- cmbCom.Sorted = True
- cmbCom.SelectedIndex = 0
- End Sub
-
- Private Sub btnStart_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnStart.Click
- Dim mBaudRate As Integer
- Dim mParity As IO.Ports.Parity
- Dim mDataBit As Integer
- Dim mStopBit As IO.Ports.StopBits
- Dim mPortName As String
-
- mPortName = cmbCom.SelectedItem.ToString
- mBaudRate = 9600
- mParity = Parity.None
- mDataBit = 8
- mStopBit = StopBits.One
-
- RS232 = New IO.Ports.SerialPort(mPortName, mBaudRate, mParity, mDataBit, mStopBit)
-
- If Not RS232.IsOpen Then
- RS232.Open()
- btnSend.Enabled = True
- Timer1.Interval = 100
- Timer1.Enabled = True
- Else
- MsgBox("通讯端口打开错误！", MsgBoxStyle.Critical)
- End If
- End Sub
-
- Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer1.Tick
- Dim InByte() As Byte, ReadCount As Integer
- If RS232.BytesToRead <= 0 Then Exit Sub
- ReDim InByte(RS232.BytesToRead - 1)
- ReadCount = RS232.Read(InByte, 0, RS232.BytesToRead)
-
- If ReadCount = 0 Then
- Exit Sub
- Else
- For Each bData As Byte In InByte
- Me.txtReceive.Text += bData.ToString & vbCrLf '若有数据则加到接收文本框
-
- Next
- End If
- End Sub
-
- Private Sub btnClose_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnClose.Click
- If RS232 Is Nothing OrElse Not RS232.IsOpen Then '尚未打开
- MsgBox("通讯端口尚未打开", MsgBoxStyle.Critical Or MsgBoxStyle.OkCancel)
- Else
- RS232.Close()
- btnStart.Enabled = False
- btnClose.Enabled = False
- Timer1.Enabled = False
- RS232 = Nothing
- End If
- End Sub
-
- Private Sub btnSend_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSend.Click
- Dim bDataOut() As Byte, Buf As String
- Dim iSentCount As Integer
- Dim Encode1 As Encoding = Encoding.ASCII '声明编码对象，使用ASCII
-
- Try
- Buf = txtSend.Text.Trim()
- bDataOut = Encode1.GetBytes(Buf) '将字符串转换为字节数组
- iSentCount = bDataOut.GetLength(0) '发送总字节数
- '显示出总字节数
- lblSentCount.Text = "总传输量：" & iSentCount.ToString & "字节"
- RS232.Write(bDataOut, 0, iSentCount)
- Catch ex As Exception
- MessageBox.Show("输入数值错误：" + ex.ToString, "错误通知", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
- End Try
- End Sub
-
- Private Sub btnEnd_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnEnd.Click
- If Not RS232 Is Nothing Then
- If RS232.IsOpen Then RS232.Close()
- End If
- End
- End Sub
-
- Private Sub cmbCom_KeyPress(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles cmbCom.KeyPress
- e.KeyChar = ChrW(0) '禁止用户在其中输入任何文字
- End Sub
- End Class
|( 京ICP备09078825号 )
发表于 2017-5-22 22:50:22
收藏
发表于 2017-6-3 04:04:30
